home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-users-of-norman / CUON_33_(10-1984).d64 / bioprt 15x (.txt) < prev    next >
Commodore BASIC  |  2019-04-13  |  4KB  |  158 lines
  1. 1 OPEN4,4
  2. 2 PRINT CHR$(147)
  3. 3 PRINT"THIS PROGRAM PLOTS YOUR BIORHYTHM CYCLES"
  4. 4 REM:     REWRITTEN BY BILL BUCHANAN
  5. 5 REM:     FOR COMMODORE 64
  6. 6 DIM F(12),T$(8),Z$(20),O$(55)
  7. 7 P=3.14159265
  8. 8 FOR I=1 TO 8:READ T$(I):NEXT
  9. 9 DATA "SUN","MON","TUE","WED","THU","FRI","SAT","   "
  10. 10 K=2*P
  11. 11 FOR I=1 TO 12:READ F(I):NEXT
  12. 12 DATA31,28,31,30,31,30,31,31,30,31,30,31
  13. 13 INPUT"BIORHYTHM FOR ";Z$
  14. 14 PRINT
  15. 15 PRINT"ENTER DATES IN THIS FORMAT MM,DD,YYYY"
  16. 16 PRINT
  17. 17 PRINT TAB(11);"BIRTHDATE:";
  18. 18 INPUT M1,D1,Y1
  19. 19 IF Y1>99 THEN 21
  20. 20 Y1=Y1+1900:PRINT Y1;" ASSUMED.  ";
  21. 21 M2=M1:D2=D1:Y2=Y1
  22. 22 GOSUB 126
  23. 23 GOSUB 145: JB=JD
  24. 24 PRINT"JULIAN DATE ";JB
  25. 25 P1=P2
  26. 26 PRINT
  27. 27 PRINT TAB(10);"START DATE:";
  28. 28 INPUT M2,D2,Y2
  29. 29 IF Y2>99 THEN 31
  30. 30 Y2=Y2+1900:PRINT Y2;" ASSUMED.  ";
  31. 31 GOSUB 126
  32. 32 GOSUB 145: JC=JD
  33. 33 PRINT"JULIAN DATE ";JC
  34. 34 AGE=JC-JB
  35. 35 PRINT
  36. 36 PRINT"NO. OF DAYS PRINTED:";
  37. 37 INPUT L
  38. 38 REM:
  39. 39 REM:     PRINT CHART HEADING
  40. 40 REM:
  41. 41 GOSUB144
  42. 42 PRINT#4:PRINT#4
  43. 43 PRINT#4,CHR$(16)"12",CHR$(14)"BIORHYTHM PROGRAM"
  44. 44 PRINT#4,CHR$(15)
  45. 45 PRINT#4
  46. 46 GOSUB 144
  47. 47 PRINT#4,"    COMPLEMENTS OF  BILL BUCHANAN [146]"
  48. 48 N=JC-JB
  49. 49 FOR I=1 TO 4:PRINT#4:NEXT
  50. 50 PRINT#4,"BIORHYTHM CHART FOR ";CHR$(27)CHR$(52)CHR$(14);Z$
  51. 51 PRINT#4,CHR$(27)CHR$(53)
  52. 52 PRINT#4,CHR$(16)"10BORN ON   ";T$(P1);"  ";M1;"/";D1;"/";Y1;"  ";
  53. 53 PRINT#4,CHR$(9)"JULIAN DATE--";JB
  54. 54 PRINT#4,CHR$(16)"10BEGINNING ";T$(P2);" ";M2;"/";D2;"/";Y2;"  ";
  55. 55 PRINT#4,CHR$(9)"JULIAN DATE--";JC
  56. 56 PRINT#4
  57. 57 PRINT#4,CHR$(16)"49AGE IN DAYS IS ";AGE
  58. 58 PRINT#4
  59. 59 PRINT#4,CHR$(16)"23P = PHYSICAL       (23 DAYS)"
  60. 60 PRINT#4,CHR$(16)"23E = EMOTIONAL      (28 DAYS)"
  61. 61 PRINT#4,CHR$(16)"23I = INTELLECTUAL   (33 DAYS)"
  62. 62 PRINT#4,CHR$(16)"23* = INTERSECTION OF ANY TWO OF P, E, OR I"
  63. 63 PRINT#4,CHR$(16)"23A = OVER-ALL AVERAGE"
  64. 64 PRINT#4:PRINT#4
  65. 65 PRINT#4,CHR$(16)"21DOWN                    CRITICAL                     UP"
  66. 66 PRINT#4,CHR$(16)"21************************!*****!************************"
  67. 67 REM SET F(2) TO 29 FOR LEAP YEARS
  68. 68 X=Y2:GOSUB 137:F(2)=F(2)+X
  69. 69 REM GENERATE THE BIO PLOT
  70. 70 L=N+L:C=0:FOR N=N TO L-1:C=C+1:FOR X=1 TO 55:O$(X)="-":NEXT X
  71. 71 O$(25)="!":O$(31)="!":Y=0
  72. 72 XP=(SIN(K*(N/23-INT(N/23)))*27)+28+.5
  73. 73 XE=(SIN(K*(N/28-INT(N/28)))*27)+28+.5
  74. 74 XI=(SIN(K*(N/33-INT(N/33)))*27)+28+.5
  75. 75 O$(XP)="P"
  76. 76 O$(XE)="E"
  77. 77 O$(XI)="I"
  78. 78 IFINT(XI)=INT(XE) OR INT(XP)=INT(XE) THEN 81
  79. 79 IF INT(XP)=INT(XI) THEN 83
  80. 80 GOTO 84
  81. 81 O$(XE)="*"
  82. 82 GOTO 84
  83. 83 O$(XP)="*"
  84. 84 Y=(XP+XE+XI)/3
  85. 85 O$(Y)="A"
  86. 86 PRINT#4,"  ";T$(P2);SPC(3);M2;"/";D2;
  87. 87 PRINT#4,CHR$(9);"  ";
  88. 88 FOR X=1 TO 55:PRINT#4,O$(X);:NEXT X:PRINT#4
  89. 89 REM:
  90. 90 REM:     INCREMENT DATE
  91. 91 REM:
  92. 92 IF P2=8 THEN 95
  93. 93 P2=P2+1
  94. 94 IF P2>7 THEN P2=1
  95. 95 D2=D2+1
  96. 96 IF D2>F(M2) THEN D2=1:M2=M2+1
  97. 97 IF M2<13 THEN 99
  98. 98 M2=1:Y2=Y2+1
  99. 99 X=Y2:F(2)=28
  100. 100 GOSUB 137:F(2)=F(2)+X:NEXT N
  101. 101 PRINT#4:PRINT#4
  102. 102 PRINT#4,"           INSTRUCTIONS"
  103. 103 PRINT#4
  104. 104 PRINT#4,"    THE BIORHYTHM THEORY..."
  105. 105 PRINT#4:PRINT#4,"    POSTULATES THAT THERE ARE CERTAIN METABOLIC CYCLES,"
  106. 106 PRINT#4,"    WHICH HAVE A CONSTANT PERIOD IN THE HUMAN BODY."
  107. 107 PRINT#4:PRINT#4,"    THERE ARE THREE (3) CYCLES..."
  108. 108 PRINT#4,"    23 DAY PHYSICAL"
  109. 109 PRINT#4,"    28 DAY EMOTIONAL"
  110. 110 PRINT#4,"    33 DAY INTELLECTUAL"
  111. 111 PRINT#4:PRINT#4,"    PHYSICAL IS ASSOCIATED WITH PHYSICAL VITALITY,"
  112. 112 PRINT#4,"    ENDURANCE AND ENERGY LEVEL."
  113. 113 PRINT#4:PRINT#4,"    EMOTIONAL CORRESPONDS TO SENSITIVITY,"
  114. 114 PRINT#4,"    INTUITION AND CHEERFULNESS."
  115. 115 PRINT#4:PRINT#4,"    INTELLECTUAL IS RELATED TO MENTAL ALERTNESS, "
  116. 116 PRINT#4,"    COGNITIVE POWER AND JUDGEMENT ABILITY.":PRINT#4
  117. 117 PRINT#4,"    ALL THREE CYCLES START AT ZERO AT THE MOMENT OF BIRTH."
  118. 118 PRINT:PRINT:INPUT"ANOTHER RUN?";V$
  119. 119 IF V$="Y" THEN 13
  120. 120 PRINT"THANK YOU...."
  121. 121 PRINT:PRINT:PRINT
  122. 122 PRINT"SEE YOU NEXT TIME."
  123. 123 CLOSE4
  124. 124 END
  125. 125 REM:
  126. 126 REM:     FIND DAY OF WEEK
  127. 127 REM:
  128. 128 N1=M2+12*INT(.6+1/M2)
  129. 129 N2=Y2-INT(.6+1/M2)
  130. 130 N3=INT(13*(N1+1)/5)
  131. 131 N4=INT(5*N2/4)
  132. 132 N5=INT(N2/100)
  133. 133 N6=INT(N2/400)
  134. 134 N7=N3+N4-N5+N6+D2-1
  135. 135 P2=N7-7*INT(N7/7)+1
  136. 136 RETURN
  137. 137 REM CHECK X FOR LEAP YEAR
  138. 138 IFX/400-INT(X/400)=0THEN141
  139. 139 IFX/100-INT(X/100)=0THEN142
  140. 140 IFX/4-INT(X/4)<>0THEN142
  141. 141 X=1:RETURN
  142. 142 X=0:RETURN
  143. 143 RETURN
  144. 144 PRINT#4,"    ";:FORI=1TO72:PRINT#4,"*";:NEXTI:PRINT#4:RETURN
  145. 145 W=0:IF M2<3 THEN W= -1
  146. 146 JD=INT(1461*(Y2+4800+W)/4)
  147. 147 B=INT(367*(M2-W*12)/12)
  148. 148 IF B<0 THEN B=B+1
  149. 149 JD=JD+B
  150. 150 B=INT(INT(3*(Y2+4900+W)/100)/4)
  151. 151 JD=JD+D2-32136-B
  152. 152 RETURN
  153. 153 REM:
  154. 154 REM:     ADAPTED FOR COMMODORE 64
  155. 155 REM:     BILL BUCHANAN
  156. 156 REM:     (405)-436-2639
  157. 157 REM:
  158.